Maintenant ,que nous avons les moyennes pondérées par les volumes : nous pouvons programmer les Macd.

Voici,le code du Macd de 2 moyennes Dema pondérées par les volumes,avec moyenne exponentielle pour calculer le signal.

Codes :

//////////macd moyenne dma pondérée par volume

//variable p =période moyenne courte--par défaut 12
//p1 = période moyenne longue -- par défaut 26
// q = période signal (trigger) -- par défaut 9

aa= close*volume
///////////////////////

bb1=dema[p](aa)
cc1=dema[p](volume)

dd1=bb1/cc1

///////////////////////////////////

bb2=dema[p1](aa)
cc2=dema[p1](volume)

dd2=bb2/cc2

////////////////////////////////

zz= dd1- dd2

zz1= exponentialaverage[q](zz)

zz2= zz-zz1  //histogramme

return zz as "macdDEMAvolume",0 as "zero",zz1 as "signal" ,zz2 as "macd-signal"

//////FIN

En étudiant les indicateurs de volume ,surtout ceux à structure intraday: j'ai imaginé de coupler le Repulse d'Eric Lefort avec l'indicateur volume.

ci-dessous deux codes :le repulsevolume ouvert et le repulsevolume borné.

voici le code :

///REPULSE VOLUME
//avec le code du dernier repulse de 2008

//variable p1 par défaut p1=1

a = 100 * ( 3 * CLOSE - 2 * LOW - OPEN ) / CLOSE
b = 100 * ( OPEN + 2 * HIGH - 3 * CLOSE ) / CLOSE

d = EXPONENTIALAVERAGE[P1](a) - EXPONENTIALAVERAGE[P1](b)

aa=cumsum(d*volume)

RETURN aa as "REPULSE VOLUME"

//////////////////////////////////////////fin


éventuellement le code du Repulse volume borné :


/////////repulse volume borné

//p1 variable du repulse --défaut =1
// p variable periode borne -défaut =10

a = 100 * ( 3 * CLOSE - 2 * LOW - OPEN ) / CLOSE
b = 100 * ( OPEN + 2 * HIGH - 3 * CLOSE ) / CLOSE

d = EXPONENTIALAVERAGE[P1](a) - EXPONENTIALAVERAGE[P1](b)

d1 = d*volume

////////////////bornage

aa=summation[p](d1)

bb=summation[p](volume)

cc = 100 *(aa/bb)

RETURN cc as "repulse volume borné", 0 as "zero"

//////////////fin


 

LE 10 MARS ,

Si vous réglez le repulse sur 5 , alors vous avez la valeur 1 du repulse lissé (  premier

code du répulse ),formule qui se trouve dans le premier livre de Eric Lefort.

ci-dessous un example:

Obv est un indicateur de volume - j'ai trouvé sur internet une variante :
 le obv multivote,en plus de la clôture ,il prend en compte le +haut et le +bas du jour.

j'ai rajouté une moyenne pondérée comme signal.


ci-dessous le code :


//MULTI-VOTE OBV
// Appeared in June 93 issue of Stocks & Commodities magazine.

////OBV MULTI-VOTE////

if high >high[1] then
 c1=1
else
 c1=-1
endif

if high = high[1] then
 c1=0
endif

if close > close[1]  then
 c2 = 1
else
 c2=-1
 
endif

if close = close[1] then
 c2=0
endif

if low > low[1] then
 
 c3 = 1
else
 c3=-1
 
endif

if low = low[1] then
 c3=0
endif

b1=cumsum(((c1+c2+c3)/3)*volume)

////////////trigger moyennemobile

//variable moyenne = p par défaut = 5

b2= weightedaverage[p](b1)

return b1 AS " OBV MULTIVOTE" ,b2 as "signal"

///////////////////////////////////////////////////////////

Cet indicateur est conseillé par John Bollinger dans son livre (les bandes..) page 17.



Pour  effectuer des comparaisons entre actions ou marchés - il suffit de créer une mesure relative.

Il faut diviser les volumes par leur moyenne  mobile à 50 jours(barres) ,puis on multipliera  le resultat par 100.

Le code pour Prorealtime : ( avec variable p pour la moyenne mobile)


//////////////////volumenormalisé
aa= volume  

//variable p par défaut 50

bb= average[p](aa)

cc= 100*(aa/bb)

return cc as "volume normalisé",100

/////////////////////////////////////////////////////////////////////////