Bonjour ,

J 'ai modifié le code Supertrend(olivier Seban) en remplaçant le prix moyen (Median price)

par la moyenne de Hull.

Vous pouvez facilement mettre la moyenne de votre choix à la place de Medianprice.

Bons trades.

CODE POUR METATRADER (IL FAUT CHARGER LES 2 INDICATEURS)

http://www.forex-tsd.com/indicators-metatrader-4/15133-supertrend-11.html

Code Prorealtime :

//////////////////////////////////////////////////////////////////////////////

/////////////////////////SUPERTREND  HULL//
////////////////////////by SOHOCOOL
/////////////////////AOUT 2011
////////////////////////////////////////////////////////////////////
///VARIABLES
//////aa = coef de  average true range  -- décimale défaut = 1
//////bb  = périodes average true range -- entier défaut =12
//////p = périodes Hull average -- entier défaut = 12

//////////////////////////////////TRUE RANGE

c1 =abs( high - low)

c2 = abs( close[1]-high )

c3 = abs ( close[1] - low )

c4 = max(c1,c2)

c5 = max(c4,c3)

/////////////////////////////AVERAGE  TRUE RANGE

atr =AVERAGE[bb](c5)

/////////////////////////////////////////////
/////////////////////////////////////////////////////////////// Moyenne = Mobile de HULL
demiP = round(P/2)
temp = 2*WeightedAverage[demiP](close) - WeightedAverage[P](close)
racineP = round(SQRT(P))
MMHULL = WeightedAverage[racineP](temp)
REM Fin Moyenne Mobile de HULL

//////////////////////////////////////////////

avg=MMHULL  ////////////////METTRE VOTRE MOYENNE ICI
up=avg+aa*atr
dn=avg-aa*atr
once trend=1
if close>up[1] then
 trend=1
elsif close<dn[1] then
 trend=-1
endif
if trend<0 and trend[1]>0 then
 flag=1
else
 flag=0
endif
if trend>0 and trend[1]<0 then
 flagh=1
else
 flagh=0
endif
if trend>0 and dn<dn[1] then
 dn=dn[1]
endif
if trend<0 and up>up[1] then
 up=up[1]
endif
if flag=1 then
 up=avg+aa*atr
endif
if flagh=1 then
 dn=avg-aa*atr
endif
if trend=1 then
 super=dn
else
 super=up
endif
return super coloured by trend  as "supertrend_HULL"
////////////////////////////////////////////////////////////////////////FIN  //  END

Bonsoir ou Boujour à tous,

Vous trouvez un Pdf ci-dessous :

http://www.mesasoftware.com/Papers/THE%20INVERSE%20FISHER%20TRANSFORM.pdf

C'est un code facile à traduire en Prorealtime ,très semblable au Easy language.

Metatrader code :

  http://codebase.mql4.com/ru/5612

Une variante :

http://codebase.mql4.com/7651

CODE PROREALTIME : 

////////////////////////////////////////////////////////

// Sohocool le 17 juillet 2010

Value1 = 0.1*(RSI[5](Close) - 50)

Value2 = WeightedAverage[9](Value1)

IFish = (Exp(2*Value2) - 1) / (Exp(2*Value2) + 1)

Return  Ifish as "Inverse Fisher Rsi",0.5 as "0.5",-0.5 as "-0.5"

/////////////////////////////////////fin / end

Bonjour à tous, 

Bandes de Bollinger avec la Moyenne de Hull et, écart type (standard deviation en Anglais)

calculée avec la moyenne Hull.

La moyenne de Hull étant très réactive: le coéfficiant des bandes doit être plus bas

au alentour de 1.

CODE PRT:

///////////////////////////////////////
/////////bandes de Bollinger avec  moyenne de Hull

//variable p = entier = période moyenne de Hull -par défaut =12
//         coef= coefficiant bande Bolinger =décimal -par défaut = 1

///////////by sohocool //  le 17/06/2011

////////////// Moyenne Mobile de HULL
demiP = round(P/2)
temp = 2*WeightedAverage[demiP](customclose) - WeightedAverage[P](customclose)
racineP = round(SQRT(P))
MMHULL = WeightedAverage[racineP](temp)
///////////////////////////////////////////////////////////

av=mmhull

//////////////////////////////////////////////////
som=0
for i=0 to p-1 do
 som = som + SQUARE( customclose[i]-av)
next
som=som / p
ecart = SQRT(som)
////////////////////////////////////////////////////////////////

bas = av - coef*ecart
haut= av + coef*ecart

/////////////////////////////////////////////////////////////////////////

return av as "moyenne Hull",bas as "band basse",haut as "bande haute"

///////////////////////////////////////////FIN

Bonsoir,

Je vous propose une interprétation de l'indicateur "Polarized Fractal Efficiency "de

Hans Hannul.

Il est construit avec l'indicateur Roc.

Voir le lien ci-dessous :

http://www.amibroker.com/library/detail.php?id=231

Code ProRealtime :

///////////////////Polarized Fractal Roc
///////////////by Sohocool
////////////////////////////////////////////////////////////////////
p  =10

t=5
///////////////////////////////////////////////////////////////////

C1= SQRT(SQUARE(ROC[9](customclose)) + 100)

C2=summation[p]( SQRT(SQUARE(ROC[1](customclose)) + 1))

sign =SGN(MOMENTUM[9](customclose))

EFF=100*SIGN*C1/C2

PF=ExponentialAverage[t](EFF)

///////////////////////////////////////////////////

RETURN PF as"Polarized_Fractal_Roc",15 as "15",-15 as"-15"

//////////////////////////////////Fin /////End

Bonjour à tous,

Bonjour Fred,

Le code Bandes de Bollinger multiples moyennes mobiles stop and reverse pour PRT

Ci dessous le lien pour indicateur MT4 :

http://forex-indicators.net/mt4-indicators/bbands_stop

Ici l'histogramme :

http://www.forex-tsd.com/indicators-metatrader-4/10228-bbands-stop-bar-2.html#post277800

On peut régler le style de l indicateur ligne façon Supertend ou Points façon S.A.R.

CODE PRT :

//////////////////////////////////////////////////////////////////////////////////////

///BBolliinger_stop_and_reverse
///By Sohocool.
///super bandes Bollinger Stop and reverse

///Variables    P =periode moyenne mobile par défaut ==22
///////////////////////s = type de la moyenne mobile par défaut =Simple
///////////////////////r = Coefficiaent ecart type (standard deviation) par défaut = 1.00 // mettre décimale
//////////////Réglage de la courbe ligne =façon Super trend ou Points façon SAR.

////////////Bands_bollinger
// ecart type = standard deviation
co=customclose
av=average[p,s](co)
som=0
for i=0 to p-1 do
 som = som + SQUARE( co[i]-av)
next
som=som / p
ecart = SQRT(som)

//cv = average[p,s](co)

up= av + r*ecart
dn= av - r*ecart

///////////////////Stop and reverse
once trend=1
if co>up[1] then
 trend=1
elsif co<dn[1] then
 trend=-1
endif
if trend<0 and trend[1]>0 then
 flag=1
else
 flag=0
endif
if trend>0 and trend[1]<0 then
 flagh=1
else
 flagh=0
endif
if trend>0 and dn<dn[1] then
 dn=dn[1]
endif
if trend<0 and up>up[1] then
 up=up[1]
endif
if flag=1 then
 up=av+r*ecart
endif
if flagh=1 then
 dn=av-r*ecart
endif
if trend=1 then
 super=dn
else
 super=up
endif
return super coloured by trend as "BBollinger_Stop_Reverse"

/////////////////////////////////Fin////End