Pour finir avec le Fisher Transform ,voici la version normale.

CODE PRT

////////////////////////////////////////////////////////////

///////FISHER TRANSFORM NORNAL V2
//////By sohocool 15/02/2011

////variable P = période canal donchian -défaut = 11,22,33,44,55 etc pour journalier.
/////////////////P1 = période du filtre exponentielle de stochastique --défaut entre 3 et 5.
////////////////P2= période du filtre exponentielle de fisher --défaut entre 3 et 5.

/////////////A1 = choix du prix : close , median price, typical price -----défaut =medianprice

a1= customclose

b1= highest[p](a1)
b2=lowest[p](a1)

if barindex > p+2 then
 
 
 vb=(a1-b2)/(b1-b2)
 
 
 v1 =exponentialaverage[p1](2*(vb - 0.5))
 
 
 f1 =exponentialaverage[p2]( 0.50*log((1+v1)/(1-v1) ))
 
endif

return f1 as "Fisher" , f1[1] as "trigger",0 as"Zero"

 ///////////////////////////////////////fin ////end

Bonjour à tous ,

Bonne Année 2012,

J'ai progammé l'histogramme ,avec la valeur 100,pour pouvoir mettre

un pourcentage indicateur à l'interieur.

Vu que la base de calcul du Ehlers Fisher Transform est une stochastique(vb),

pour la version V1 ,on va mettre la stochastique filtrée par une moyenne

exponentielle de période = 5 (soit exponentialaverage[5](100*vb).

CODE PROREALTIME :

///////////FISHER TRASFORM HITOGRAM_V1

//////By sohocool 18/11/2011

////variable P = periode canal donchian -défaut = 10

a1= customclose

b1= highest[p](a1)

b2=lowest[p](a1)

if barindex > p+2 then

vb=(a1-b2)/(b1-b2)

v1 =0.66*((vb )- 0.5)   + 0.67*v1[1]

f1 = 0.5*log((1+v1)/(1-v1) )+0.5*f1[1]

endif

if f1 >=f1[1] then

hh= 100

else

hh=0

endif

if f1 < f1[1] then

hh1= 100

else

hh1=0

endif

sto = exponentialaverage[5](100*vb)

return hh coloured(0,255,0) as "histo up",hh1 coloured(255,0,0) as "histo down",sto coloured(0,0,255) as "Stochastique",20 as "20",80 as "80"

/////////////////////fin ///end //code

Bonjour à tous,

Voici ,la traduction en language PRT du code de Elder's fait par José Silva ,c'est une

 interpretation.

Le lien : http://trader-online.tk/MSZ/e-w-Elders_AutoEnvelope.html

Code Prorealtime.

//////////////////////SOHOCOOL
///////////////////////ELDER 'S AUTO ENVELOPES PROREALTIME
///////////////////////28  AOUT 2011
{Elder's AutoEnvelope by Jose Silva

{Dr A. Elder's AutoEnvelope interpretation v1.0
Differs from the original in that it avoids
the use of the hindsight-based LastValue()
MetaStock function.
www.elder.com/MetaStock/AutoEnvelope.htm

http://www.metastocktools.com }

{ User inputs }
{pds:=Input("EMA periods",1,252,21);
pdsBak:=Input("lookback periods",1,252,42);
x:=Input("use: Open=1, High=2, Low=3, Close=4, WClose=5",1,5,4);
plot:=Input("[1]AutoEnvelope, [2]Long signals, [3]All signals",1,3,1);
delay:=Input("Entry/Exit signals delay",0,5,0);

{ Price field }
{x:=If(x=1,O,If(x=2,H,If(x=3,L,If(x=5,WC(),C))));
    
    { Envelope bands
    Avg:=Mov(x,pds,E);
    hiAvg:=HHV(H,pdsBak);
    loAvg:=LLV(L,pdsBak);
    shift:=
    Mov(If(hiAvg>Avg,hiAvg-Avg,Avg-loAvg),pds,E);
     UpperBand:=Avg+shift;
     LowerBand:=Avg-shift;}
     
     
     ///variable pds = périodes de la moyenne exponentielle (défaut =22)
     ///variable pdsback = période du canal donchian (défaut = 44) (le double).
     
     
     //price field
     
     x = customclose
     { Envelope bands }
     Avg= ExponentialAverage[pds](x)
     hiAvg=Highest[pdsback](high)
     loAvg=Lowest[pdsback](low)
     ////////////////////////////////////////////////////////////////////////////////////
     if hiavg >=avg then
      
      shift= exponentialaverage[pds](hiavg -avg)
     else
      
      shift=exponentialaverage[pds](avg-loavg)
      
     endif
     
     
     ////////////////////////////////////////////////////////////////////////////
     UpperBand=Avg+shift
     LowerBand=Avg-shift
     
     
     /////////////////////////////////////////////////////////////
     
     
     return avg as "exponentielle",upperband as "bande haute",lowerband as" bande basse"

////////////////////////////////////////////fin///end ///code

Bonjour,

Je vous propose le code du Rsi Inverse Fisher de Sylvain Vervoort,vu sur Metatrader.

Le principe d'utilisation est simple :

Quand le Rsi inverse croise à la baisse le niveau haut ,on vend.

Quand le Rsi inverse croise à la hausse le niveau bas ,on achète .

Bon trades.

CODE PROREALTIME:

///////////////////////////////////////////////////////////////////////////////////////////////////////////////

//SVE RSI INVERSE FISHER
//by SOHOCOOL le 18 /11/2011

//Variables :
//rsiperiod = période du rsi / par défaut = 4
//emaperiod = période de moyenne zero lag (dema) /  par défaut =4
//levelup = niveau haut / par défaut =88
//leveldown = niveau bas / par défaut =12

//calculate rainbow

wma0= weightedaverage[2](close)

wma1 = weightedaverage[2](wma0)
wma2 = weightedaverage[2](wma1)
wma3= weightedaverage[2](wma2)
wma4 = weightedaverage[2](wma3)
wma5 = weightedaverage[2](wma4)
wma6 = weightedaverage[2](wma5)
wma7 = weightedaverage[2](wma6)
wma8 = weightedaverage[2](wma7)
wma9 = weightedaverage[2](wma8)

rainbow = (5 * wma0 + 4 * wma1 + 3 * wma2 + 2 * wma3 + wma4 + wma5 + wma6+ wma7 + wma8+ wma9) / 20

//---- calculate rsi from rainbow smoothed price curve

rainrsi = 0.1 * (RSI[rsiperiod](rainbow) - 50)

//---- smooth the rsi with Vervoort zero lag MA
ema0 = exponentialaverage[emaperiod](rainrsi)
ema1 = exponentialaverage[emaperiod](ema0)
srsi= 2*ema0- ema1
//---- do the fish
fish = 50*((Exp(2 * srsi) - 1) / (EXP(2 * srsi) + 1) + 1)

//----

return fish as "SVE Rsi I Fisher",leveldown as "niveau bas",levelup as "niveau haut"
///////////////////////FIN DU CODE ////END

Code pour Metatrader :

http://codebase.mql4.com/7651